generated_hpp = []
generated_cpp = []

subdir('Checkpoint')
subdir('Duration')
subdir('Statistic')

boot_time_monitor_dbus_deps = [
  dependency('phosphor-dbus-interfaces'),
  sdbusplus_dep
]

boot_time_monitor_dbus_lib = library(
  'boot_time_monitor-dbus',
  generated_hpp,
  generated_cpp,
  implicit_include_directories: false,
  include_directories: boot_time_monitor_incs,
  version: meson.project_version(),
  dependencies: boot_time_monitor_dbus_deps,
  install: true)

boot_time_monitor_dbus_dep = declare_dependency(
  dependencies: boot_time_monitor_dbus_deps,
  sources: [generated_hpp, generated_cpp],
  link_with: boot_time_monitor_dbus_lib)

boot_time_monitor_dbus_reqs = []
foreach dep : boot_time_monitor_dbus_deps
  if dep.type_name() == 'pkgconfig'
    boot_time_monitor_dbus_reqs += dep
  endif
endforeach

import('pkgconfig').generate(
  boot_time_monitor_dbus_lib,
  description: 'Boot Time Monitor DBus Bindings',
  version: meson.project_version(),
  requires: boot_time_monitor_dbus_reqs)