gtest = dependency('gtest', main: true, disabler: true, required: false)
gmock = dependency('gmock', disabler: true, required: false)
if not gtest.found() or not gmock.found()
  gtest_proj = import('cmake').subproject(
    'googletest',
    cmake_options: [
      '-DCMAKE_CXX_FLAGS=-Wno-pedantic',
    ],
    required: false)
  if gtest_proj.found()
    gtest = declare_dependency(
      dependencies: [
        dependency('threads'),
        gtest_proj.dependency('gtest'),
        gtest_proj.dependency('gtest_main'),
      ])
    gmock = gtest_proj.dependency('gmock')
  else
    assert(not get_option('tests').enabled(), 'Googletest is required')
  endif
endif

boot_time_monitor_test_incs = include_directories('include')

tests = [
  'utils_test',
  'boot_manager_test',
]

foreach t : tests
  test(t, executable(t.underscorify(), t + '.cpp',
                     build_by_default: false,
                     include_directories : boot_time_monitor_test_incs,
                     implicit_include_directories: false,
                     dependencies: [boot_time_monitor_dep, gtest, gmock]))
endforeach