gtest = dependency('gtest', main: true, disabler: true, required: false)
gmock = dependency('gmock', disabler: true, required: false)
if not gtest.found() or not gmock.found()
    gtest_proj = import('cmake').subproject('googletest', required: false)
    if gtest_proj.found()
        gtest = declare_dependency(
            dependencies: [
                dependency('threads'),
                gtest_proj.dependency('gtest'),
                gtest_proj.dependency('gtest_main'),
            ]
        )
        gmock = gtest_proj.dependency('gmock')
    else
        assert(
            not get_option('tests').enabled(),
            'Googletest is required if tests are enabled'
        )
    endif
endif

test(
    'test_utils',
    executable(
        'test_utils',
        'rde_test.cpp',
        dependencies: [gtest],
        implicit_include_directories: false,
    )
)

test(
    'test_mctp_setup',
    executable(
        'test_mctp_setup',
        'mctp_setup_test.cpp',
        dependencies: [gtest, req_src, stdplus],
        implicit_include_directories: true,
    )
)