devpath_plugin/meson.build

protoc = find_program('protoc')
protobuf_dep = dependency('protobuf')

devpath_mapping_proto_gen = custom_target(
  'redfish_to_uhm_mapping_proto',
  output: ['redfish_to_uhm_mapping.pb.cc', 'redfish_to_uhm_mapping.pb.h'],
  input: ['redfish_to_uhm_mapping.proto'],
  command: [
    protoc,
    '@INPUT@',
    '--proto_path=@CURRENT_SOURCE_DIR@',
    '--cpp_out=@OUTDIR@',
  ],
)

devpath_mapping_proto_dep = declare_dependency(
  sources: devpath_mapping_proto_gen,
  dependencies: protobuf_dep,
  include_directories: include_directories('.'),
)

devpath_plugin_deps = [
  devpath_mapping_proto_dep,
  dependency('absl_flat_hash_map'),
  dependency('absl_strings'),
  tlbmc_lib_dep,
]

devpath_plugin_lib = static_library(
  'devpath_plugin',
  'redfish_to_uhm_trie.cpp',
  'redfish_to_uhm_trie_node.cpp',
  'redfish_devpath_injector.cpp',
  include_directories: incdir,
  dependencies: devpath_plugin_deps,
)

devpath_plugin_dep = declare_dependency(
  link_with: devpath_plugin_lib,
  dependencies: devpath_plugin_deps,
  include_directories: incdir,
)