recipes-google/flash/bmc-bios-update.inc

PR = "r1"
LICENSE = "CLOSED"
LIC_FILES_CHKSUM = ""

inherit systemd

PROVIDES += "virtual/bios-update"
RPROVIDES:${PN} += "virtual/bios-update"

PACKAGES += "${PN}-hooks"
SYSTEMD_PACKAGES += "${PN}-hooks"

FILESEXTRAPATHS:prepend := "${THISDIR}/bmc-bios-update:"

RDEPENDS:${PN}:append = " \
  bios-validator \
  bash \
  flashupdate \
"

FILES:${PN}-hooks += "\
    ${systemd_system_unitdir}/bios-update-powercycle-hook.service \
"

BIOS_HELPER = "${@bb.utils.contains('DISTRO_FEATURES', 'oob-firmware-update', 'bios-helper-ttf.sh', 'bios-helper.sh', d)}"

SRC_URI = " \
  file://bios-common.sh \
  file://bios-update-powercycle-hook.sh \
  file://bios-update.sh \
  file://bios-verify.sh \
  file://bios-version.sh \
  file://bios-update-powercycle-hook.service \
  file://bios-version@.service \
  file://phosphor-ipmi-flash-bios-update.service \
  file://phosphor-ipmi-flash-bios-verify@.service \
  file://${BIOS_HELPER} \
"

SYSTEMD_SERVICE:${PN} += " \
  bios-version@.service \
  phosphor-ipmi-flash-bios-update.service \
  phosphor-ipmi-flash-bios-verify@.service \
"

SYSTEMD_SERVICE:${PN}-hooks += " \
  bios-update-powercycle-hook.service \
"

do_install() {
  install -d ${D}${libexecdir}
  install -m 0755 ${WORKDIR}/bios-common.sh ${D}${libexecdir}
  install -m 0755 ${WORKDIR}/${BIOS_HELPER} ${D}${libexecdir}/bios-helper.sh

  install -d ${D}${bindir}
  install -m 0755 ${WORKDIR}/bios-update-powercycle-hook.sh ${D}${bindir}
  install -m 0755 ${WORKDIR}/bios-update.sh ${D}${bindir}
  install -m 0755 ${WORKDIR}/bios-verify.sh ${D}${bindir}
  install -m 0755 ${WORKDIR}/bios-version.sh ${D}${bindir}

  install -d ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/bios-update-powercycle-hook.service ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/bios-version@.service ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/phosphor-ipmi-flash-bios-update.service ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/phosphor-ipmi-flash-bios-verify@.service ${D}${systemd_system_unitdir}
}