recipes-google/g3-shared-libs/g3-shared-libs_git.bb

SUMMARY = "Protos and libraries shared across repos from piper"
DESCRIPTION = "The recipe delivers miscellaneous protos and libraries \
that we copied from piper via copybara"
PR = "r1"
PV = "0.1+git${SRCPV}"
LICENSE = "CLOSED"

SRC_URI = "git://gbmc-private.googlesource.com/g3-shared-libs/;protocol=https;branch=master"
SRCREV = "8601e9dcbe3752f2910da4b08213a97b6aa035f2"

inherit meson pkgconfig

S = "${WORKDIR}/git"

DEPENDS += "abseil-cpp"
DEPENDS += "grpc"
DEPENDS += "nlohmann-json"
DEPENDS += "openssl"
DEPENDS += "protobuf"

# Package compile configurations
# In most cases, platform's bbappend won't touch PACKAGECONFIG
PACKAGECONFIG ??= "gmi one zatar"

PACKAGECONFIG[gmi] = "\
  -Dgmi=enabled, \
  -Dgmi=disabled, \
  protobuf protobuf-native, \
"

PACKAGECONFIG[one] = "\
  -Done=enabled, \
  -Done=disabled, \
  protobuf protobuf-native abseil-cpp, \
"

PACKAGECONFIG[zatar] = "\
  -Dzatar=enabled, \
  -Dzatar=disabled, \
"

# Package install configurations
PACKAGES:prepend = " \
  ${PN}-gmi \
  ${PN}-one \
"

FILES:${PN}-gmi = " \
  ${libdir}/libgmi_protos${SOLIBS} \
  ${includedir}/gmi\* \
"

FILES:${PN}-one = " \
  ${libdir}/libone${SOLIBS} \
  ${includedir}/one/* \
"