recipes-google/nvme/nvmed.bb

SUMMARY = "nvmed"
DESCRIPTION = "An NVMe MI management stack for OpenBMC"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
DEPENDS = " \
    boost \
    i2c-tools \
    libgpiod \
    libnvme \
    liburing \
    nlohmann-json \
    phosphor-logging \
    protobuf \
    protobuf-native \
    sdbusplus \
    ${PYTHON_PN}-sdbus++-native \
    phosphor-dbus-interfaces \
    shared-memory \
    "

SRC_URI = "git://gbmc.googlesource.com/dbus-sensors;protocol=https;branch=google-dev \
           file://override.conf"

# Modify these as desired
PV = "1.0+git"
SRCREV = "eb04dd8195b341204d05cf2d2c41051c241ee410"

S = "${WORKDIR}/git"

inherit pkgconfig meson systemd

EXTRA_OEMESON:append = " \
    -Dcpp_std=c++23 \
    -Dadc=disabled \
    -Dexit-air=disabled \
    -Dexternal=disabled \
    -Dfan=disabled \
    -Dhwmon-temp=disabled \
    -Dintel-cpu=disabled \
    -Dintrusion=disabled \
    -Dipmb=disabled \
    -Dmcu=disabled \
    -Dpsu=disabled \
    -Dtests=disabled \
"

# Enable the nvmed
EXTRA_OEMESON:append = " \
    -Dnvme=enabled \
    -Dbuild-type=bitbake \
"

SYSTEMD_SERVICE:${PN} += "xyz.openbmc_project.nvmesensor.service"
FILES:${PN} += "${systemd_system_unitdir}/xyz.openbmc_project.nvmesensor.service.d/override.conf"

do_install:append() {
    install -d ${D}${systemd_system_unitdir}/xyz.openbmc_project.nvmesensor.service.d
    install -m 0644 ${WORKDIR}/override.conf ${D}${systemd_system_unitdir}/xyz.openbmc_project.nvmesensor.service.d/
}