recipes-google/pldmd/pldmd-file-transfer_git.bb

SUMMARY = "PLDM stack for file transfer"
DESCRIPTION = "PLDM responder stack for file transfer protocol"
PR = "r1"
PV = "0.1+git${SRCPV}"

LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"

inherit meson pkgconfig systemd

S = "${WORKDIR}/git"
# TODO(b/482144905): We need to update the CI and submit this patch
# https://gbmc-review.googlesource.com/c/pldm/+/107844. Have a patch to get the bitbake build
# working first.
SRC_URI = "git://gbmc.googlesource.com/pldm;protocol=https;branch=file-transfer \
           file://service-override.conf \
           file://0001-use-stdexec-inline_scheduler.patch \
           "
SRCREV = "7b75e716740bf30524fe6655d2803429f9838767"

DEPENDS += " \
  boost \
  cli11 \
  libpldm-google \
  nlohmann-json \
  phosphor-dbus-interfaces \
  phosphor-logging \
  stdplus \
  systemd \
"

EXTRA_OEMESON:append:gbmc = " \
   -Dtests=disabled \
   -Dsoftoff=disabled \
   -Doem-ibm=disabled \
   -Doem-ampere=disabled \
   -Dtransport-implementation=af-mctp \
   -Dgenerate-terminus-locator-pdr=disabled \
   -Dmctp-reactor=disabled \
   -Dlibpldm:oem=[] \
   -Duse-libpldm-subproject=false \
"

SYSTEMD_SERVICE:${PN} = "pldmd.service"

do_install:append() {
    rm -rf ${D}${datadir}/pldm
    install -d ${D}${datadir}/pldm/pdr

    # Remove conflicting libpldm files installed by the meson subproject
    rm -f ${D}${libdir}/libpldm.so*
    rm -rf ${D}${includedir}/libpldm
    rm -f ${D}${libdir}/pkgconfig/libpldm.pc

    # Install systemd service override
    install -d ${D}${systemd_system_unitdir}/pldmd.service.d
    install -D -m 0644 ${WORKDIR}/service-override.conf \
        ${D}${systemd_system_unitdir}/pldmd.service.d/
}

FILES:${PN} += " \
    ${datadir}/libpldm \
    ${datadir}/pldm \
    ${systemd_system_unitdir}/pldmd.service.d/service-override.conf \
"