recipes-connectivity/mctp/mctp_%.bbappend

FILESEXTRAPATHS:prepend:gbmc := "${THISDIR}/${PN}:"

SRCREV:gbmc = "f41eca70ca1891e47a9b0923242f197e3fe269e4"
SRC_URI:append:gbmc = " \
  file://mctp-i2c.service \
  file://init-mctp-i2c-endpoint.sh \
  file://service-override.conf \
  file://0001-mctpd-ignore-IIDs-validation-for-control-responses.patch \
  file://0002-use-RTA_OIF-Outgoing-Interface-route-in-gbmc.patch \
  file://0003-mctpd-remove-MCTP-endpoints-behind-MCTP-bridge.patch \
  file://0004-mctp-remove-peer-if-get-properties-fails.patch \
  file://0005-mctpd-don-t-error-out-in-case-of-mismatch-length.patch \
"

RDEPENDS:${PN} += " \
    bash \
"

EXTRA_OEMESON:append:gbmc = " \
    -Dtests=false \
"

# Base MCTP EID used by init-mctp-i2c-endpoint.sh
# This variable can be override by other layers
EID_BASE ??= "60"

FILES:${PN}:append:gbmc = " \
  ${systemd_system_unitdir}/mctpd.service.d/service-override.conf \
"

do_install:append:gbmc() {
    # -i'' : Replace in-place without backup file
    sed -i'' -E ${WORKDIR}/init-mctp-i2c-endpoint.sh \
        -e "s#EID_BASE=[0-9]+#EID_BASE=${EID_BASE}#"

    install -d ${D}${bindir}
    install -m 0755 ${WORKDIR}/init-mctp-i2c-endpoint.sh ${D}${bindir}/

    install -d ${D}${systemd_system_unitdir}
    install -m 0644 ${WORKDIR}/mctp-i2c.service ${D}${systemd_system_unitdir}/

    install -d ${D}${systemd_system_unitdir}/mctpd.service.d
    install -D -m 0644 ${WORKDIR}/service-override.conf \
      ${D}${systemd_system_unitdir}/mctpd.service.d/
}


SYSTEMD_SERVICE:${PN} += " mctp-i2c.service"