recipes-google/bmc-crypto-key/bmc-crypto-key.bb

SUMMARY = "Encryption key config for bmc-crypto"
PR = "r1"

LICENSE = "CLOSED"
LIC_FILES_CHKSUM = ""

DEPENDS += "jq-native"

FILES:${PN} += "/usr/share/bmc-crypto/key.json"

BMC_CRYPTO_SYSTEM_FILE_PATH ?= ""
BMC_CRYPTO_OFFSET ?= ""
BMC_CRYPTO_SYSTEM_BACKUP_FILE_PATH ?= ""
BMC_CRYPTO_BACKUP_OFFSET ?= ""

do_install:append() {
  if [ -z '${BMC_CRYPTO_SYSTEM_FILE_PATH}' ]; then
    echo 'Missing BMC_CRYPTO_SYSTEM_FILE_PATH' >&2
    exit 1
  fi

  if [ -z '${BMC_CRYPTO_OFFSET}' ]; then
    echo 'Missing BMC_CRYPTO_OFFSET' >&2
    exit 1
  fi

  if [ -n '${BMC_CRYPTO_SYSTEM_BACKUP_FILE_PATH}' ]; then
    if [ -z '${BMC_CRYPTO_BACKUP_OFFSET}' ]; then
      echo 'Missing BMC_CRYPTO_BACKUP_OFFSET' >&2
      exit 1
    fi

    echo '{"sysFilePath": "${BMC_CRYPTO_SYSTEM_FILE_PATH}", "offset": ${BMC_CRYPTO_OFFSET}, "sysBackupFilePath": "${BMC_CRYPTO_SYSTEM_BACKUP_FILE_PATH}","backupOffset": ${BMC_CRYPTO_BACKUP_OFFSET}}' | \
      jq . > ${WORKDIR}/config.json
  else
    echo '{"sysFilePath": "${BMC_CRYPTO_SYSTEM_FILE_PATH}","offset": ${BMC_CRYPTO_OFFSET}}' | \
    jq . > ${WORKDIR}/config.json
  fi

  install -d ${D}/usr/share/bmc-crypto/
  install -m 0644 ${WORKDIR}/config.json ${D}/usr/share/bmc-crypto/key.json
}