recipes-google/googleapis/googleapis_git.bb

SUMMARY = "Interface proto definitions of public Google APIs"
DESCRIPTION = "This repository contains the original interface definitions of \
public Google APIs that support both REST and gRPC protocols."
PR = "r1"
PV = "1.0+git${SRCPV}"

DEPENDS = "grpc-native"
RDEPENDS:${PN} += " bash"

SRC_URI = "git://github.com/googleapis/googleapis.git;protocol=https;branch=master"
SRCREV = "46ccf213d569425e0334885428946856b62b2b99"

S = "${WORKDIR}/git"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"

OUTPUT = "${WORKDIR}/build"
LANGUAGE = "cpp"
GRPCPLUGIN = "${STAGING_BINDIR_NATIVE}/grpc_${LANGUAGE}_plugin"

EXTRA_OEMAKE += "OUTPUT=${OUTPUT} LANGUAGE=${LANGUAGE} GRPCPLUGIN=${GRPCPLUGIN} PROTOINCLUDE=${STAGING_INCDIR_NATIVE}"

do_configure() {
    :
}

# Install googleapis generated headers and protos in native for compiling its dependencies
do_install(){
  install -d ${D}${includedir}/google/rpc/
  cp -r ${OUTPUT}/google/* ${D}${includedir}/google/

  install -d ${D}${datadir}/googleapis/google/
  cp -r ${S}/google/* ${D}${datadir}/googleapis/google/

  # Remove conflict files between protobuf package
  rm ${D}${includedir}/google/protobuf/struct.pb.h
  rm ${D}${includedir}/google/protobuf/wrappers.pb.h
  rm ${D}${includedir}/google/protobuf/empty.pb.h
  rm ${D}${includedir}/google/protobuf/timestamp.pb.h
  rm ${D}${includedir}/google/protobuf/field_mask.pb.h
  rm ${D}${includedir}/google/protobuf/type.pb.h
  rm ${D}${includedir}/google/protobuf/duration.pb.h
  rm ${D}${includedir}/google/protobuf/descriptor.pb.h
  rm ${D}${includedir}/google/protobuf/source_context.pb.h
  rm ${D}${includedir}/google/protobuf/any.pb.h
  rm ${D}${includedir}/google/protobuf/api.pb.h
  rm ${D}${includedir}/google/protobuf/compiler/plugin.pb.h
  rm ${D}${includedir}/google/protobuf/cpp_features.pb.h
}

FILES:${PN} = " \
  ${includedir}/google/ \
  ${includedir}/google/**.h \
  ${includedir}/google/**.cc \
  ${datadir}/googleapis/google/ \
  ${datadir}/googleapis/google/**.proto \
"