recipes-google/pldmd/pldmd-google_git.bb

HOMEPAGE = "https://gbmc.googlesource.com/pldm"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
SRC_URI = "git://gbmc.googlesource.com/pldm;branch=google-dev;protocol=https"
SRCREV = "a033585e340c130cf08220f841b8d5bf2b1391d3"

SUMMARY = "PLDM Stack (Google Fork)"
DESCRIPTION = "Implementation of the PLDM specifications"
DEPENDS += "function2"
DEPENDS += "systemd"
DEPENDS += "sdeventplus"
DEPENDS += "phosphor-dbus-interfaces"
DEPENDS += "nlohmann-json"
DEPENDS += "cli11"
DEPENDS += "libpldm"
DEPENDS += "phosphor-logging"
DEPENDS += "stdplus"
DEPENDS += "sdbusplus"
PV = "1.0+git${SRCPV}"
PR = "r1"

S = "${WORKDIR}/git"
SYSTEMD_SERVICE:${PN} += "pldmd.service"

inherit meson pkgconfig
inherit systemd

PACKAGECONFIG[transport-af-mctp] = "-Dtransport-implementation=af-mctp"
PACKAGECONFIG ??= " transport-af-mctp"

EXTRA_OEMESON = " \
        -Dtests=disabled \
        -Doem-ibm=disabled \
        -Dsoftoff=disabled \
        -Dampere=disabled \
        -Dmetrics-dump-period=600 \
        "

FILESEXTRAPATHS:prepend:gbmc := "${THISDIR}/pldm-scripts:"

FILES:${PN} += " \
  ${libdir}/tmpfiles.d \
"

SRC_URI:append:gbmc = " \
  file://pldm_update_fw.sh \
  file://pldm_dump_fw_status.sh \
  file://pldm_list_fw_version.sh \
"

RDEPENDS:${PN} += " \
    bash \
"

do_install:append:gbmc () {
    rm -rf ${D}/usr/share
    install -d ${D}${bindir}
    install -m 0755 ${WORKDIR}/pldm_update_fw.sh ${D}${bindir}/
    install -m 0755 ${WORKDIR}/pldm_dump_fw_status.sh ${D}${bindir}/
    install -m 0755 ${WORKDIR}/pldm_list_fw_version.sh ${D}${bindir}/
}