recipes-google/pldmd/pldmd-google-dev-common_git.bb

SUMMARY = "PLDM stack for google-dev-common"
DESCRIPTION = "PLDM responder stack for google-dev-common"
PR = "r1"
PV = "0.1+git${SRCPV}"

LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"

inherit meson pkgconfig systemd

S = "${WORKDIR}/git"
SRC_URI = "git://gbmc.googlesource.com/pldm;protocol=https;branch=google-dev-common"
SRCREV = "8bb94e2e642a5326b444d10f9b8e7b36e24b39f9"

DEPENDS += " \
  boost \
  cli11 \
  function2 \
  libpldm-google \
  nlohmann-json \
  phosphor-dbus-interfaces \
  phosphor-logging \
  sdbusplus \
  sdeventplus \
  stdplus \
  systemd \
"

EXTRA_OEMESON:append:gbmc = " \
   -Dtests=disabled \
   -Dsoftoff=disabled \
   -Doem-ibm=disabled \
   -Doem-ampere=disabled \
   -Doem-meta=disabled \
   -Dtransport-implementation=af-mctp \
   -Duse-libpldm-subproject=false \
   -Duse-phosphor-dbus-interfaces-subproject=false \
"

SYSTEMD_SERVICE:${PN} = "pldmd.service"

do_install:append() {
    rm -rf ${D}${datadir}/pldm
    install -d ${D}${datadir}/pldm/pdr
}

FILES:${PN} += " \
    ${datadir}/libpldm \
    ${datadir}/pldm \
"