recipes-google/s4/gpowerd_git.bb

SUMMARY = "gPowerD s4 local agent"
DESCRIPTION = "Provides a gRPC interface for managing system power events"
PR = "r1"
PV = "0.1+git${SRCPV}"
LICENSE = "CLOSED"
inherit meson pkgconfig systemd

DEPENDS += " \
  fmt \
  grpc \
  grpc-native \
  zatar \
  boost \
  nlohmann-json \
  gtest \
  util-linux-native \
  xxd-native \
  "

EXTRA_OEMESON="-Dinsecure_mode=disable -Dloas3-validation=enabled"
S = "${WORKDIR}/git"

SRC_URI = "git://gbmc.googlesource.com/gPowerD;protocol=https;branch=master"
SRCREV = "a74f36e306435203e7ef54d9dc3214295e35b9d9"

SRC_URI += " \
  file://gpowerd.service \
  file://43-gbmc-gpowerd.rules \
  file://gpowerd_authz_policy.json.prod \
  file://gpowerd_authz_policy.json.dev \
"

SYSTEMD_PACKAGES = "${PN}"
SYSTEMD_SERVICE:${PN} += "gpowerd.service"

do_install:append() {
  install -d ${D}/var/google/
  install -d ${D}/var/google/gPowerD/
  install -d ${D}/var/google/gPowerD/SavedActions/

  install -d ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/gpowerd.service ${D}${systemd_system_unitdir}

  install -Dm 0644 ${WORKDIR}/43-gbmc-gpowerd.rules \
          ${D}${sysconfdir}/nftables/43-gbmc-gpowerd.rules

  install -Dm 0644 ${S}/bmc/machine_configs/${MACHINE}.textproto ${D}/etc/gpowerd/gpowerd_config.proto
}


do_install:append:gbmc:prod() {
  install -d ${D}/var/google/authz_policies/
  install -m 0644 ${WORKDIR}/gpowerd_authz_policy.json.prod ${D}/var/google/authz_policies/gpowerd_authz_policy.json
}

do_install:append:gbmc:dev() {
  install -d ${D}/var/google/authz_policies/
  install -m 0644 ${WORKDIR}/gpowerd_authz_policy.json.dev ${D}/var/google/authz_policies/gpowerd_authz_policy.json
}