recipes-google/debug/strowger_git.bb

SUMMARY = "Strowger - Remote Debug Service over gRPC"
DESCRIPTION = "Strowger - Remote Debug Service over gRPC"
PR = "r1"
PV = "0.1+git${SRCPV}"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"

inherit meson pkgconfig systemd

DEPENDS += "boost"
DEPENDS += "grpc"
DEPENDS += "grpc-native"
DEPENDS += "protobuf"
DEPENDS += "protobuf-native"

S = "${WORKDIR}/git"
SRC_URI = "git://gbmc.googlesource.com/strowger;branch=master;protocol=https"
SRCREV = "7e309c6e2a71fd51989eda193f4345a4be6a7eaa"

SRC_URI += " \
  file://gbmc-strowgerd.rules \
  file://strowgerd.service \
  file://strowgerd_authz_policy_dev.json \
  file://strowgerd_authz_policy_prod.json \
"

SYSTEMD_PACKAGES = "${PN}"
SYSTEMD_SERVICE:${PN} += "strowgerd.service"

do_install:append() {
  install -d ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/strowgerd.service ${D}${systemd_system_unitdir}

  install -Dm 0644 ${WORKDIR}/gbmc-strowgerd.rules \
          ${D}${sysconfdir}/nftables/gbmc-strowgerd.rules
}

do_install:append:gbmc:prod() {
  install -d ${D}/etc/google/authz_policies/
  install -m 0644 ${WORKDIR}/strowgerd_authz_policy_prod.json ${D}/etc/google/authz_policies/strowgerd_authz_policy.json
}

do_install:append:gbmc:dev() {
  install -d ${D}/etc/google/authz_policies/
  install -m 0644 ${WORKDIR}/strowgerd_authz_policy_dev.json ${D}/etc/google/authz_policies/strowgerd_authz_policy.json
}