recipes-kernel/linux/linux-gbmc.inc

inherit kernel
require recipes-kernel/linux/linux-yocto.inc

PROVIDES += "virtual/kernel"
KCONFIG_MODE = "--allnoconfig"
PV = "${LINUX_VERSION}+git${SRCPV}"

SRC_URI += " \
  git://gbmc.googlesource.com/linux;protocol=https;branch=${KBRANCH} \
  file://DOWNSTREAM_0001-ARM-dts-gbmc-Add-flash-layouts.patch \
  file://DOWNSTREAM_0002-mtd-spi-nor-macronix-Add-google-compatible-flash-IDs.patch \
  "

FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
SRC_URI += "file://defconfig"
SRC_URI:append:dev = " file://dev.cfg"
SRC_URI:append:npcm7xx = " file://npcm7xx.cfg"

SRC_URI:append:aspeed-g6 = " \
  file://0001-net-ftgmac100-Support-for-fixed-PHYs.patch \
  file://DOWNSTREAM_0002-kernel-Ensure-only-3-byte-read-command-can-be-sent.patch \
  file://0003-net-ftgmac100-Add-scu-reset-toggling.patch \
  file://0003-ftgmac100-enlarge-the-ring-size.patch \
"

# Aspeed eMMC driver fixes.
# The commit "mmc-aspeed-fix-sdhci-software-reset-can-t-be-cleared" allows us
# to recover from any sdhci errors. That fix resolves b/267685954, where we
# found that some machines hit sdhci errors during initialization, which the
# driver couldn't recover from, leaving the eMMC unusable until the BMC reboots.
# The other 3 patches are dependencies needed by that fix.
SRC_URI:append:aspeed-g6 = " \
  file://0001-sdhci-aspeed-Add-SDR50-support.patch \
  file://0002-arm-dts-aspeed-Change-eMMC-device-compatible.patch \
  file://0003-mmc-aspeed-Adjust-delay-taps-calculation-method.patch \
  file://0004-mmc-aspeed-fix-sdhci-software-reset-can-t-be-cleared.patch \
"

do_compile_headers() {
  oe_runmake -C ${S} O=${B} headers
}

do_shared_headers() {
  cp -r ${B}/usr/include/ ${STAGING_KERNEL_BUILDDIR}
}

addtask do_compile_headers after do_configure
addtask do_shared_headers after do_shared_workdir do_compile_headers