| FILESEXTRAPATHS:prepend:gbmc := "${THISDIR}/${PN}:" |
| |
| SRCREV:gbmc = "69ed224ff9b5206ca7f3a5e047a9da61377d2ca7" |
| SRC_URI:append:gbmc = " \ |
| file://0001-mctpd-Set-initial-route-MTU-to-minimum.patch \ |
| file://mctp-i2c.service \ |
| file://init-mctp-i2c-endpoint.sh \ |
| " |
| |
| RDEPENDS:${PN} += " \ |
| bash \ |
| " |
| |
| EXTRA_OEMESON:append:gbmc = " \ |
| -Dtests=false \ |
| " |
| |
| # Base MCTP EID used by init-mctp-i2c-endpoint.sh |
| # This variable can be override by other layers |
| EID_BASE ??= "60" |
| |
| do_install:append:gbmc() { |
| # -i'' : Replace in-place without backup file |
| sed -i'' -E ${WORKDIR}/init-mctp-i2c-endpoint.sh \ |
| -e "s#EID_BASE=[0-9]+#EID_BASE=${EID_BASE}#" |
| |
| install -d ${D}${bindir} |
| install -m 0755 ${WORKDIR}/init-mctp-i2c-endpoint.sh ${D}${bindir}/ |
| |
| install -d ${D}${systemd_system_unitdir} |
| install -m 0644 ${WORKDIR}/mctp-i2c.service ${D}${systemd_system_unitdir}/ |
| } |
| |
| |
| SYSTEMD_SERVICE:${PN} += " mctp-i2c.service" |
