recipes-kernel/linux/linux-gbmc_aspeedg7.bb

require linux-gbmc.inc

KERNEL_VERSION_SANITY_SKIP = "1"
LINUX_MAJOR = "6.6"
LINUX_VERSION = "${LINUX_MAJOR}.93"
PV = "aspeedg7-${LINUX_VERSION}"
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"

S = "${WORKDIR}/linux-${LINUX_MAJOR}"

SRC_URI:prepend = " \
  ${KERNELORG_MIRROR}/linux/kernel/v6.x/linux-${LINUX_MAJOR}.tar.xz;sha256sum=d926a06c63dd8ac7df3f86ee1ffc2ce2a3b81a2d168484e76b5b389aba8e56d0 \
  ${KERNELORG_MIRROR}/linux/kernel/v6.x/patch-${LINUX_VERSION}.xz;sha256sum=5cf8db0daba2311c9dc3cfe95d7895e7217896520c49927f6e3dd2b6538b81f1 \
  "

SRC_URI:append = " \
  file://0001-jffs2-add-RENAME_EXCHANGE-support.patch \
  file://0001-mux-Make-it-possible-to-select-MULTIPLEXER-if-EXPERT.patch \
  file://0001-hwmon-Add-driver-for-MPS-MPQ8785-Synchronous-Step-Do.patch \
  file://0001-hwmon-pmbus-Add-ltc4286-driver.patch \
  file://0001-hwmon-max34451-Workaround-for-lost-page.patch \
  file://0001-PRODKERNEL-platforms-i2c-I2C-over-USB-driver.patch \
  file://0001-platforms-i2c-i2c-usb-update-a-few-nits.patch \
  "

SRC_URI:append:aspeed-g7 = " \
  file://aspeed-g7-gbmc.cfg \
  "

# TODO(b/386134258): ask Aspeed to upstream below
# All these dirvers are porting from SDK v09.07 kernel
# https://github.com/AspeedTech-BMC/linux/commits/aspeed-master-v6.6/
# SHA: e6cd1b0ff7798c191ddfddeec0b600374a5d2ed9
SRC_URI:append:aspeed-g7 = " \
    file://0001-Add-arch-files-for-ast2700.patch \
    file://0002-Add-dt-bindings-head-file-for-ast2700.patch \
    file://0003-Add-reset-controller-driver-for-ast2700.patch \
    file://0004-Add-irqchip-driver-for-ast2700.patch \
    file://0005-Add-pinctrl-driver-for-ast2700.patch \
    file://0006-Add-clk-driver-for-ast2700.patch \
    file://0007-Add-uart-vuart-udma-drvier-for-ast2700.patch \
    file://0008-Add-SPI-driver-for-ast2700.patch \
    file://0009-Add-watchdog-driver-for-ast2700.patch \
    file://0010-Add-net-ftgmac-driver-for-ast2700.patch \
    file://0011-Add-gpio-sgpio-driver-for-ast2700.patch \
    file://0012-Add-i2c-driver-for-ast2700.patch \
    file://0013-Add-emmc-driver-for-ast2700.patch \
    file://0014-Add-jtag-driver-for-ast2700.patch \
    file://0015-Add-ADC-driver-for-ast2700.patch \
    file://0016-Add-RTC-driver-for-ast2700.patch \
    file://0017-Add-i3c-driver-for-ast2700.patch \
    file://0018-Add-SOC-drivers-for-ast2700.patch \
    file://0019-Add-RNG-driver-for-ast2700.patch \
    file://0020-Add-crypto-driver-for-ast2700.patch \
    file://0021-Add-USB-uhci-ehci-driver-for-ast2700.patch \
    file://0022-Add-USB-Virtual-Hub-Controller-driver-for-ast2700.patch \
    file://0023-Add-PCIe-RC-driver-for-ast2700.patch \
    file://0024-Add-SGMII-and-USB3-phy-driver-for-ast2700.patch \
    file://0025-bus-Add-Aspeed-LTPI-bus-controller-driver.patch \
    file://0026-Add-LTPI-GPIO-driver-for-ast2700.patch \
    file://0027-Add-DRAM-EDAC-driver-for-ast2700.patch \
    file://0028-mctp-i3c-MCTP-I3C-driver.patch \
    file://0029-soc-aspeed-ast2700-epsi-Fix-eDAF-memory-mapping-in-H.patch \
"

SRC_URI:append:aspeed-g7 = " \
    file://0002-dt-bindings-i3c-hub-Document-I3C-Hub-bindings.patch \
    file://0003-i3c-i3c-hub-Add-I3C-Hub-driver.patch \
    file://0004-i3c-i3c-hub-Finish-all-work-before-adding-i2c-adapte.patch \
    file://0005-i3c-i3c-hub-Wait-rx-done-instead-of-tx-done.patch \
    file://0006-i3c-hub-Fix-compilation-error.patch \
    file://0009-mipi-i3c-hci-disable-DMA-experimental.patch \
    file://0010-Fix-the-i3c-hub-node-mismatch-issue.patch \
    file://i3c-hub.cfg \
"

# Server3.0 ast2750 customized patches
SRC_URI:append:aspeed-g7 = " \
    file://0027-Add-setting-SGPIO-default-value.patch  \
    file://0030-data-transfer-to-reserved-memory-for-edaf.patch \
"

KCONFIG_MODE="--allnoconfig"
# TODO(b/373416015) Remove this to enable CONFIGCHECK
GBMC_CONFIGCHECK = "0"

# Override poky/meta/classes-recipe/kernel-yocto.bbclass
# Note: Applying patch-${LINUX_VERSION}.xz requires the presence of .gitignore
# in the kernel source. We do not remove this file.
do_kernel_checkout() {
	set +e

	source_dir=`echo ${S} | sed 's%/$%%'`
	source_workdir="${WORKDIR}/git"

	# case: we have no git repository at all. 
	# To support low bandwidth options for building the kernel, we'll just 
	# convert the tree to a git repo and let the rest of the process work unchanged

	# if ${S} hasn't been set to the proper subdirectory a default of "linux" is 
	# used, but we can't initialize that empty directory. So check it and throw a
	# clear error

	cd ${S}
	if [ ! -f "Makefile" ]; then
		bberror "S is not set to the linux source directory. Check "
		bbfatal "the recipe and set S to the proper extracted subdirectory"
	fi
	git init
	check_git_config
	git add .
	git commit -q -n -m "baseline commit: creating repo for ${PN}-${PV}"
	git clean -d -f

	set -e
}