recipes-google/gbmc-sysinit/gbmc-sysinit_server3.bb

SUMMARY = "gBMC System Initialization Service for Server 3.0"
DESCRIPTION = "Verify the BIOS and release initalize the system"
PR = "r1"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"

require gbmc-sysinit.inc

FILESEXTRAPATHS:prepend := "${THISDIR}/server3:"

SRC_URI += " \
  file://gbmc_sysinit.sh \
  file://gbmc_sysinit_helper.sh \
  file://wait_emmc_available.sh \
  file://acpi-s0@.service \
  file://gbmc-sysinit@.service \
  file://emmc-wait.service \
  file://pcie-bifurcation-override.conf \
"

FILES:${PN}:append = " \
  ${systemd_system_unitdir}/gbmc-sysinit@.service.d/prodid-override.conf \
  ${systemd_system_unitdir}/gbmc-sysinit@.service.d/pcie-bifurcation-override.conf \
"

SYSTEMD_SERVICE:${PN}:append = " \
  gbmc-sysinit@.service \
  acpi-s0@.service \
  emmc-wait.service \
"

do_install:append () {
  install -d ${D}${bindir}
  install -m 0755 ${WORKDIR}/gbmc_sysinit.sh ${D}${bindir}/
  install -m 0755 ${WORKDIR}/wait_emmc_available.sh ${D}${bindir}/

  install -d ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/acpi-s0@.service \
      ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/gbmc-sysinit@.service \
      ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/emmc-wait.service \
      ${D}${systemd_system_unitdir}

  install -d ${D}${datadir}/${PN}
  install -m 0755 ${WORKDIR}/gbmc_sysinit_helper.sh ${D}${datadir}/${PN}

  install -d ${D}${systemd_system_unitdir}/gbmc-sysinit@.service.d
  install -m 0644 ${WORKDIR}/prodid-override.conf \
    ${D}${systemd_system_unitdir}/gbmc-sysinit@.service.d/
  install -m 0644 ${WORKDIR}/pcie-bifurcation-override.conf \
    ${D}${systemd_system_unitdir}/gbmc-sysinit@.service.d/
}

HOST_NODES ??= "0 1"

pkg_postinst:${PN} () {
  for node in ${HOST_NODES};
  do
    systemctl --root=$D enable gbmc-sysinit@${node}.service
    systemctl --root=$D enable acpi-s0@${node}.service
  done
}