| SUMMARY = "Transport-Independent RPC library" |
| DESCRIPTION = "Libtirpc is a port of Suns Transport-Independent RPC library to Linux" |
| SECTION = "libs/network" |
| HOMEPAGE = "http://sourceforge.net/projects/libtirpc/" |
| BUGTRACKER = "http://sourceforge.net/tracker/?group_id=183075&atid=903784" |
| LICENSE = "BSD-3-Clause" |
| LIC_FILES_CHKSUM = "file://COPYING;md5=f835cce8852481e4b2bbbdd23b5e47f3 \ |
| file://src/netname.c;beginline=1;endline=27;md5=f8a8cd2cb25ac5aa16767364fb0e3c24" |
| |
| PROVIDES = "virtual/librpc" |
| |
| SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${BP}.tar.bz2 \ |
| file://0001-libtirpc-fix-bindresvport-build-with-clang-22-C23.patch \ |
| " |
| UPSTREAM_CHECK_URI = "https://sourceforge.net/projects/libtirpc/files/libtirpc/" |
| UPSTREAM_CHECK_REGEX = "(?P<pver>\d+(\.\d+)+)/" |
| SRC_URI[sha256sum] = "b47d3ac19d3549e54a05d0019a6c400674da716123858cfdb6d3bdd70a66c702" |
| |
| inherit autotools pkgconfig |
| |
| PACKAGECONFIG ??= "\ |
| ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} \ |
| " |
| PACKAGECONFIG:append:libc-musl = " rpcdb" |
| |
| PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6" |
| PACKAGECONFIG[gssapi] = "--enable-gssapi,--disable-gssapi,krb5" |
| PACKAGECONFIG[rpcdb] = "--enable-rpcdb,--disable-rpcdb," |
| |
| do_install:append() { |
| test -e ${D}${sysconfdir}/netconfig && chown root:root ${D}${sysconfdir}/netconfig |
| } |
| |
| BBCLASSEXTEND = "native nativesdk" |
