upstream-layers/meta-openembedded/meta-oe/recipes-multimedia/audiofile/audiofile_0.3.6.bb

DESCRIPTION = "The Audio File Library provides a uniform and elegant \
API for accessing a variety of audio file formats, such as AIFF/AIFF-C, \
WAVE, NeXT/Sun .snd/.au, Berkeley/IRCAM/CARL Sound File, Audio Visual \
Research, Amiga IFF/8SVX, and NIST SPHERE."
HOMEPAGE = "http://www.68k.org/~michael/audiofile/"
SECTION = "libs"
LICENSE = "LGPL-2.0-only & GPL-2.0-only"
LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
                    file://COPYING.GPL;md5=b234ee4d69f5fce4486a80fdaf4a4263"

SRC_URI = " \
    ${GNOME_MIRROR}/audiofile/0.3/${BP}.tar.xz \
    file://run-ptest \
    file://0001-fix-negative-shift-constants.patch \
    file://0002-fix-build-on-gcc6.patch \
    file://0003-fix-CVE-2015-7747.patch \
    file://0004-Always-check-the-number-of-coefficients.patch \
    file://0005-clamp-index-values-to-fix-index-overflow-in-IMA.cpp.patch \
    file://0006-Check-for-multiplication-overflow-in-sfconvert.patch \
    file://0007-Actually-fail-when-error-occurs-in-parseFormat.patch \
    file://0008-Check-for-multiplication-overflow-in-MSADPCM-decodeS.patch \
    file://0001-test-sign.cpp-Fix-C-narrowing-errors.patch \
    file://test-for-CVE-2015-7747.patch \
    file://CVE-2019-13147.patch \
    file://CVE-2022-24599.patch \
    file://CVE-2018-13440.patch \
    file://CVE-2018-17059.patch \
"
SRC_URI[sha256sum] = "ea2449ad3f201ec590d811db9da6d02ffc5e87a677d06b92ab15363d8cb59782"

inherit autotools lib_package pkgconfig ptest

CACHED_CONFIGUREVARS += "ac_cv_prog_cc_c23=no"

DEPENDS = " \
    asciidoc-native \
    alsa-lib \
    libogg \
    flac \
"

do_compile_ptest(){
    oe_runmake -C gtest libgtest.la
    cd test
    # Query the TESTS variable value, remove the $(...) parts from it,
    # compile as make target along with FLAC (which is an optional test)
    oe_runmake `make -p | grep "^TESTS = " | sed 's/$([^)]*)//g' | cut -d= -f2` FLAC
}

do_install_ptest(){
    install -d ${D}${PTEST_PATH}/test
    for t in test/.libs/*; do
        install $t ${D}${PTEST_PATH}/test/
    done
}